Record GPS Position Log

In this guide you will learn how to play back a previously recorded GPS position log, using DataSource on an interactive map, and use this as input to record a GPS position log using DataSourceRecorder. Prior to recording, the sensor data types to be recorded are selected and their availability is validated. A frame per second (FPS) counter is also displayed.

GPS Log Data Source

First, get an API key token, see the Getting Started guide.

Qt should be installed to continue.

The Maps SDK for Qt should be installed, see the Setup Maps SDK for Qt guide.

Overview

RecordGPSPositionLog demonstrates how easy it is to record a GPS position log using a previously recorded GPS position log file as input, so that GPS log recording can be demonstrated on a desktop computer as well. Typically, the GPS log data source is the GPS sensor on a device, such as a phone.

The previously recorded GPS log input can be a *.nmea file, which can also be generated using free web-based nmea generator tools.

This example generates a *.gm file, intended for debugging.

Prior to recording, the sensor data types to be recorded are selected interactively by the user, then their availability is validated, and the unavailable sensor data sources are deselected automatically.

How it works

In Qt, go to the File menu and select Open File or Project…

then browse to the RecordGPSPositionLog example folder and open RecordGPSPositionLog.pro

You may want to have a look at Setting your API Key to see how to open and configure a project and set your API Key.

In main.qml, in the Component.onCompleted: block, the datasource is set by specifying the filename of a previously recorded (or web-generated) [GPS] position log, strasbourg.nmea in this case:

ServicesManager.dataSource.playbackFile = Qt.resolvedUrl("strasbourg.nmea");
ServicesManager.dataSource.type = DataSource.Type.Playback;

This implies that the strasbourg.nmea data file is located in the project directory of this example, and configured in the qml.qrc file, so that Qt.resolvedUrl() can find it.

Additionally, the following options are set for the GPS log data source recorder:

ServicesManager.dataSourceRecorder.chunkDurationMinutes = 1;
ServicesManager.dataSourceRecorder.continuousRecording = true;
ServicesManager.dataSourceRecorder.deleteOlderThanKeepMin = false;
ServicesManager.dataSourceRecorder.keepMinMinutes = 60;
ServicesManager.dataSourceRecorder.dataSourceTypesToRecord = DataSourceRecorder.Position;

The minimum size of a GPS log is 1 minute, set in chunkDurationMinutes; the keepMinMinutes setting specifies the size of the moving window of recorded GPS log data to keep, implying that data older than this amount of time, in minutes, is deleted.

The deleteOlderThanKeepMin flag set to false indicates that no data shall be deleted, all recorded GPS log data is kept. This may be useful for testing purposes.

Position is the raw location (GPS) sensor data, and is always on for navigation, as recording a GPS position log without position makes no sense. ImprovedPosition is the map-matched computed position, for example, placing the actual position on a nearby road. Multiple data sources / sensors can be selected by OR-ing them together using the | bitwise operator.

The content type that will be downloaded upon demand is also specified:

let updater = ServicesManager.contentUpdater(ContentItem.Type.RoadMap);

The MapView displaying the interactive map has 4 buttons:

Start / Stop recording and Faster / Slower playback in the top left corner;

Playback - switch to live / Live - switch to playback in the lower left corner; and

Follow position in the lower right corner.

Select source and sensors

CheckBox {
    id: checkBattery
    enabled: !ServicesManager.dataSourceRecorder.active
    checked: false
    indicator.width: 18
    indicator.height: 18
    text: qsTr("Battery")
}
CheckBox {
    id: checkCompass
    enabled: !ServicesManager.dataSourceRecorder.active
    checked: false
    indicator.width: 18
    indicator.height: 18
    text: qsTr("Compass")
}
CheckBox {
    id: checkImprovedPosition
    enabled: !ServicesManager.dataSourceRecorder.active
    checked: true
    indicator.width: 18
    indicator.height: 18
    text: qsTr("ImprovedPosition") //calculated, map-matched position
}

Additionally, on the right margin, checkboxes for sensors that can be selected to be recorded are displayed. The user can select any or all of these. The Position sensor checkbox is not enabled because that is the location (GPS) sensor, which is always recorded in a position (GPS) log.

Button {
    id: livePlaybackButton
    enabled: !ServicesManager.dataSourceRecorder.active
    anchors.left: parent.left
    anchors.bottom: parent.bottom
    text: ServicesManager.dataSource.type === DataSource.Type.Live
          ? "Live - switch to playback" : "Playback - switch to live"
    background: Rectangle {
        opacity: parent.hovered ? 1 : 0.5
        color: enabled ? parent.down ? "#aa00aa" :
                                       (parent.hovered ? "#0000ff" : "#2000ff") : "#aaaaaa"
    }
    palette { buttonText: "#ffffff"; }
    onClicked: {
        ServicesManager.dataSource.type =
                ServicesManager.dataSource.type === DataSource.Type.Live
                ? DataSource.Type.Playback : DataSource.Type.Live;
    }
}

The button to switch between live and playback input data source sets the ServicesManager.dataSource.type qml property to either DataSource.Type.Playback or DataSource.Type.Live

The Live/Playback data source must be selected before recording starts. In a real on the road navigation, the Live data source is selected for GPS log recording. To demonstrate GPS log recording functionality on a desktop computer, a playback data source (.nmea file included in this example) is used, so Playback is selected.

Start recording

Button {
    id: startStopButton
    text: ServicesManager.dataSourceRecorder.active
          ? "Stop recording" : "Start recording"
    background: Rectangle {
        opacity: parent.hovered ? 1 : 0.5
        color: enabled ? parent.down ? "#aa00aa" :
                                       (parent.hovered ? "#0000ff" : "#2000ff") : "#aaaaaa"
    }
    palette { buttonText: "#ffffff"; }
    onClicked: {
        //validate available data types only if switching recording to on
        if (!ServicesManager.dataSourceRecorder.active) {
            //position (raw GPS sensor input) is always recorded
            ServicesManager.dataSourceRecorder.dataSourceTypesToRecord = DataSourceRecorder.Position
                    | (checkAcceleration.checked ? DataSourceRecorder.Acceleration : 0)
                    | (checkBattery.checked ? DataSourceRecorder.Battery : 0)
                    | (checkCamera.checked ? DataSourceRecorder.Camera : 0)
                    | (checkCompass.checked ? DataSourceRecorder.Compass : 0)
                    | (checkMagneticField.checked ? DataSourceRecorder.MagneticField : 0)
                    | (checkOrientation.checked ? DataSourceRecorder.Orientation : 0)
                    | (checkImprovedPosition.checked ? DataSourceRecorder.ImprovedPosition : 0)
                    | (checkTemperature.checked ? DataSourceRecorder.Temperature : 0);
            //clear checkboxes of unavailable datatypes, as those can not be recorded
            if (!ServicesManager.dataSourceRecorder.isDataTypeAvailable(DataSourceRecorder.Acceleration))
                checkAcceleration.checked = false;
            if (!ServicesManager.dataSourceRecorder.isDataTypeAvailable(DataSourceRecorder.Battery))
                checkBattery.checked = false;
            if (!ServicesManager.dataSourceRecorder.isDataTypeAvailable(DataSourceRecorder.Camera))
                checkCamera.checked = false;
            if (!ServicesManager.dataSourceRecorder.isDataTypeAvailable(DataSourceRecorder.Compass))
                checkCompass.checked = false;
            if (!ServicesManager.dataSourceRecorder.isDataTypeAvailable(DataSourceRecorder.MagneticField))
                checkMagneticField.checked = false;
            if (!ServicesManager.dataSourceRecorder.isDataTypeAvailable(DataSourceRecorder.Orientation))
                checkOrientation.checked = false;
            if (!ServicesManager.dataSourceRecorder.isDataTypeAvailable(DataSourceRecorder.ImprovedPosition))
                checkImprovedPosition.checked = false;
            if (!ServicesManager.dataSourceRecorder.isDataTypeAvailable(DataSourceRecorder.Temperature))
                checkTemperature.checked = false;
        }
        //start/stop recording position (GPS) log
        ServicesManager.dataSourceRecorder.active = !ServicesManager.dataSourceRecorder.active;
    }
}

Then click Follow position so the camera follows the green position arrow, and click Start recording to start the GPS logger.

Before recording actually starts, the sensors for the selected checkboxes are validated to verify their availability. Those sensors that are not available for recording on the current device, are automatically unchecked.

The available sensors from the user selected list of sensors are then OR-ed together in an int bitfield which is then set into the ServicesManager.dataSourceRecorder.dataSourceTypesToRecord property.

The checkboxes are disabled while recording is active because it is not possible to change the recorded datasources while recording. To do that, stop recording first, then select the desired datasources.

Recording is started by setting the ServicesManager.dataSourceRecorder.active property to true, and is stopped by setting this property to false. While recording is active, it is not possible to change data sources (live/playback) or recorded data types, so those controls are disabled. The live/playback button is enabled/disabled using its id and the enabled property: livePlaybackButton.enabled

Follow position

Button {
    anchors.right: parent.right
    anchors.bottom: parent.bottom
    text: qsTr("Follow position")
    enabled: !mapView.followingPosition
    background: Rectangle {
        opacity: parent.hovered ? 1 : 0.5
        color: enabled ? parent.down ? "#aa00aa" :
                                       (parent.hovered ? "#0000ff" : "#2000ff") : "#aaaaaa"
    }
    palette { buttonText: "#ffffff"; }
    onClicked: mapView.followingPosition = true
}

The follow position button is enabled only if the camera is not already following the green position arrow on the map.

Follow position means that the camera flies to the position of the green arrow and then follows the simulated position arrow. This is necessary, as the arrow is likely to be located elsewhere on the map, not at the current location of the camera.

The green position arrow plays back the previously recorded positions on the map, from the data source specified above.

If the map is panned/dragged to one side, the camera no longer follows the green position arrow, and the Follow position button is activated again, so it can be clicked to resume following the position arrow.

Playback speed

Button {
    text: ServicesManager.dataSource.playbackSpeedMultiplier == 9
          ? "Slower playback" : "Faster playback"
    background: Rectangle {
        opacity: parent.hovered ? 1 : 0.5
        color: enabled ? parent.down ? "#aa00aa" :
                                       (parent.hovered ? "#0000ff" : "#2000ff") : "#aaaaaa"
    }
    palette { buttonText: "#ffffff"; }
    onClicked: {
        ServicesManager.dataSource.playbackSpeedMultiplier =
                ServicesManager.dataSource.playbackSpeedMultiplier == 9 ? 1 : 9;
    }
}

The faster/slower playback button toggles the playback speed between 1x (normal) and 9x (visibly fast).

Next, click Faster playback to see that the simulation runs faster.

Click Slower playback to see that the simulation runs again at normal speed.

Stop and save recording

Click Stop recording after at least 1 minute elapsed after Start recording was clicked, or after the playback ends, to save the recorded GPS log. Recordings shorter than 1 minute are not saved.

The GPS log file has a .gm extension and is saved in this directory: ~/.local/share/APPNAME/ where APPNAME in this case is the name of this example, RecordGPSPositionLog The .gm file can be used as playback input just like an .nmea GPS log file.

Implementation details

The MapView interactive map has these settings for display and user touch input:

id: mapView
anchors.fill: parent
viewAngle: 25
zoomLevel: 69
viewPerspective: MapView.ViewPerspective.View3D
buildingsVisibility: MapView.BuildingsVisibility.Show3D
detailsQualityLevel: MapView.DetailsQualityLevel.Medium
gestures: MapView.Gesture.Pan
    | MapView.Gesture.PanEnableVelocity
    | MapView.Gesture.Pinch
    | MapView.Gesture.Rotate
    | MapView.Gesture.Tilt

anchors.fill: parent causes the map to fill the containing viewport, which is Window in this case. The zoomLevel has a higher value, the closer the camera is to the ground.

Text {
   anchors.right: parent.right
   anchors.top: parent.top
   text: fpsCounter.fps
}

The frames-per-second (fps) counter is displayed in the top right corner of the map.

<RCC>
   <qresource prefix="/">
      <file>main.qml</file>
      <file>strasbourg.nmea</file>
   </qresource>
</RCC>

The qml.qrc file lists the strasbourg.nmea GPS position log file.

QML Examples

Maps SDK for Qt Examples can be downloaded or cloned with Git